home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
The 640 MEG Shareware Studio 2
/
The 640 Meg Shareware Studio CD-ROM Volume II (Data Express)(1993).ISO
/
comm
/
cs_mac06.zip
/
COMMO.MAC
< prev
next >
Wrap
Text File
|
1992-08-23
|
30KB
|
611 lines
┌────────────────────────────────┐
│ Chuck Seyboldt's COMMO Macro │ CS-MAC06:COMMO.MAC
└────────────────────────────────┘
* Edit lines with a "!" in the first column.
* Thanks to Fred Brucker for Commo and to Jim Bennett for many
* excellent macro suggestions.
* This version of CS-MAC is radically different from earlier versions.
* It comes in several parts. See CS-MAC.MAC for the bulk of the text.
* Links from COMMO.FON are at the extreme end of COMMO.MAC
* With this line in COMMO.SET, Commo starts with the :start macro
* └──┴─────> {mac=start} Startup macro label
* I use the :start tool for easy portability from one machine to another.
* Many directories are defined here. They could all have the same name,
* but you wouldn't do that (would you?).
─────────────────────────────────────────────────────────────────────────────
┌─────────────────┐
│ Startup Macro │ In COMMO.SET, {mac=start} Startup macro label
└─────────────────┘
{:start} {clea}
! {setv ins_dir,%_hom%ins} ;for docs & instructions
! {setv savedir,%_hom%sav} ;for capture files
! {setv utildir,c:\util} ;for utility programs
! {setv qwkdr,d:\qwk} ;for .QWK files
! {setv repdr,d:\qwk} ;for .REP files
! {setv dosdir,c:\dos} ;another place for UTIL
! {setv ramdr,i:} ;for FASTest responses
! {setv ext_ed,%ramdr\q.exe} ;define external editor
! {setv ext_li,%ramdr\l.com} ;define external lister
! {setv pk_zip,%utildir\zip.exe} ;name for ZIP program
! {setv pk_un,%utildir\zipx.exe} ;name for UNZIP program
! {setv mprot,z} ;protocol for mail fetchin
! {setv name,Chuck Seyboldt} ;for various uses
! {capt n,%savedir\%_mon%%_day.cap} ;establish capture filename
! {setv rflag,aln} ;return flag for multidial
{}
{:retu} {retu} ;Very handy labelname
─────────────────────────────────────────────────────────────────────────────
* Tradename Author Myname
* Support files in my %ramdr are: LIST.COM (Vern Buerg) l.com
* QEDIT.EXE (Sam Mitchell) q.exe
* DSZ.COM (Chuck Forsberg) dsz.com
* as well as the requisite COMMAND.COM
* Support files in my %dosdir are: COMMOPNS.EXE (Shad Muegge)
* HSLINK.EXE (Sam Smith)
* Support files in my %utildir are: PHONE.EXE (Johnathan Wayne)
* DFR.COM (Gordon Haff)
* MJOG.COM (Chris Dunford)
* Support file in my %ins_dir are: COMMO.DOC
* MACRO.DOC
* The Home key uses LIST to read docs.
* The %savedir is important: WHATEVER.CAP (session captures)
* USED-ACT.%abbr% (ACTION-file history)
* ADDRESS (address book)
* RING.LOG (timestamp of RINGs)
* The Commo %_hom% directory has: ASSIGN.KEY (one-page-help screen)
* ACTION.%abbr% (ACTION-file to be run)
* COMMO.MAC \
* TABLE.MAC \ Components
* LOGON.MAC > of CS-MAC
* ACTION.MAC / Linked to
* CS-MAC.MAC / each other
* RINGLOG.MAC \
* DOSFUNC.MAC > Aux facilities
* MOSTHOST.MAC /
upld
Send a File UpLoad Protocols
╒════════════════╕
│ Zmodem │ {call cpu} {exec-n %dszprog port %_por ha bo sz -m @%_hom%files.zup} {}
│ Zmodem/REP │ {inpu bbsid,.REP to Upload} {ifex %repdr\%bbsid.rep,,no_rep} {exec-N %dszprog port %_por ha bo sz -mu %repdr%\%bbsid%.rep} {:no_rep} {}
│ Ymodem/G │ {call cpu} {symo-gk @%_hom%files.zup} {}
│ 1k-Xmodem │ {setv proto,1K-Xmodem} {call gfnu} {sxmo-k %file} {setv proto} {}
│ Xmodem CRC │ {setv proto,Xmodem-CRC}{call gfnu} {sxmo %file} {setv proto} {}
│ HS/Link │ {call cpu} {exec-n %dosdir%\hslink.exe -@ -I2 -NV -P%_por% @%_hom%files.zup} {}
│ │
│ ASCII │ {setv proto,ASCII} {call gfnu} {ascii-e %file} {}
╘════════════════╛
downld
Receive a File DownLoad Protocols
╒════════════════╕
│ Zmodem │ {exec-n %dszprog port %_por rz -mr %dldir} {}
│ Zmodem/QWK │ {exec-n %dszprog port %_por rz -m %qwkdr} {}
│ Ymodem/G │ {rymo-gy %dldir} {}
│ 1k-Xmodem │ {setv file,%dldir%\} {inpu file,Filename to Download (1k-Xmodem)} {rxmo %file} {}
│ Xmodem CRC │ {setv file,%dldir%\} {inpu file,Filename to Download (Xmodem CRC)} {rxmo %file} {}
│ HS/Link │ {exec-n %dosdir%\hslink.exe -@ -C -I2 -NV -P%_por% -R -O -K -U%dldir} {}
│ Ymodem │ {rymo-y %dldir} {}
│ ASCII │ {call chm} {}
╘════════════════╛
Call Download Menu {:pgd} {macr downld} {retu}
Call Upload Menu {:pgu} {macr upld} {retu}
Pick N Send {:cpu} {exec-n cd %dldir}
{exec-d %dosdir%\commopns.exe %_hom%files.zup -F}
{retu}
Get UL FileNm {:gfnu} {setv file,%uldir\%mask} {setv dmask} {setv mask}
{inpu file,Filename for %proto% upload (.ZIP default)}
{ifex %file,retu}
{leng %uldir} {setv dr_len,%_len}
{leng %file} {setv f_len,%_len}
{incr dr_len} {decr f_len,%dr_len} {incr dr_len}
{instring file,.} {ifco chek}
{setv file,%file%.zip}
{:chek} {ifex %file,retu}
{:mask} {subs dmask,%dr_len,1,%file}
{subs mask,%dr_len,%f_len,%file}
{exec-nw5 dir %uldir%\%dmask%*.*}
{goto gfnu}
Name U/L Dir {:alu} {setv count,0}
{:conf} {incr count}
{sete-p0 ul%count}
{inpu uldir,Select Upload directory (omit trailing"\")}
{ifex %uldir\NUL,retu,alu}
{:ul1} {setv uldir,d:\co\dl} {goto conf}
{:ul2} {setv uldir,%ramdr} {goto conf}
{:ul3} {setv uldir,%repdr} {goto conf}
{:ul4} {setv uldir,d:\co} {setv count,0} {goto conf}
menu_ed
Edit A File Choose File to Edit
╒═══════════════════════╕
│ Edit any file │ {call nf5} {}
│ Edit TABLE.MAC │ {exec-n %ext_ed %_hom%table.mac} {}
│ Edit LOGON.MAC │ {exec-n %ext_ed %_hom%logon.mac} {}
│ Edit ACTION.MAC │ {exec-n %ext_ed %_hom%action.mac} {}
│ Edit CS-MAC.MAC │ {exec-n %ext_ed %_hom%cs-mac.mac} {}
│ Edit MACROBBS.MAC │ {exec-n %ext_ed %_hom%macrobbs.mac} {}
│ Edit ASSIGN.KEY │ {edit %_hom%assign.key} {}
│ Edit ADDRESS Book │ {edit %savedir\address} {}
│ Edit Upgrade Instruct │ {edit %ins_dir\setup.ins} {}
╘═══════════════════════╛
│ Edit COMMO.MAC via CS │ {macl cs-mac.mac,ed_cmac}
Editing Menu {:ale} {macr menu_ed} {}
macr_do
Run a Macro Choose Macro to Run
╒═══════════════════════╕
Add BBS to TABLE │ CS-MAC.MAC,new_bbsid │ {macl cs-mac.mac,new_bbsid}
Run ACTION processor │ ACTION.MAC, action │ {macl action.mac,action}
RingLOG Macro {:sf5} │ RINGLOG.MAC,g01 │ {macl ringlog.mac,g01}
DosFunc Macro {:nf9} │ DOSFUNC.MAC,g01 │ {macl dosfunc.mac,g01}
Make ACTION {:alf} │ ACTION.MAC, alf │ {macl action.mac,alf}
Load HOST Mode {:af5} │ MACROBBS.MAC,bbs │ {macl macrobbs.mac,bbs}
│ │
│ │
╘═══════════════════════╛
Run a Macro menu {:alm} {macr macr_do} {}
┌───────────────────────┐
│ Toggle CAPTURE mode │
└───────────────────────┘
{:chm} {comp capture,on} {ifco cof}
{setv capture,on}
{capt y,%savedir\%_mon%%_day%.cap}
{exec-n echo OPENED ■ %_dat %_tim^j>> %_cap} {retu}
{:cof} {setv capture} {capture n}
{exec-n echo CLOSED ■ %_dat %_tim^j■-■-■>> %_cap} {retu}
*---* General *---*
Any Command at all {:alw} {setv file}
{inpu file,Enter any DOS Command:} {exec-W %file} {}
Test Command here: {:gr*} {:cla} {disp ,63,07,%_dwt %_dat%^m} {}
*---* Terminal Control *---*
Hang Up Modem {:alq} {hang} {}
Toggle Signal Lights {:al0} {ligh} {}
Toggle Mister Sound {:al3} {soun} {}
Toggle Local Echo {:al6} {loca} {}
Access Connect Parms {:all} {dpar} {}
Clear display & more {:alc} {parm ,,,,} {clea} {setv abbr} {}
Toggle Status Line {:al-} {statusline} {retu}
┌───────────────────────┐
│ Toggle Doorway Mode │
└───────────────────────┘
* This doorway mode toggle has a feature that you need to be aware of.
* It is setup to send the "drop to DOS" command to a PCBoard host.
* You may want to take those "!" lines right out of the picture.
{:al=} {sete-p0 retu}
{comp dway} {ifco ,ext}
{setv dway,9 y|}
! {inpu dway,Host Doorway Command?}
! PCBoard Drop to DOS command {send %dway} You probably want this out!
{doorway-m0} {}
{:ext} {doorway-m0}
{setv dway}
! Return from DOS to PCBoard {send exit|} {} Remove this line too!
*---* Send Strings *---*
Send Name {:nf1} {send ~~%name|} {retu}
Send Password {:nf2} {send %_pas|} {retu}
Send Signature {:nf0}
!{send Chuck∙S|~|~SN|}{}
*---* Utilities *---*
DSZ terminal shell {:af1} {exec-d %dszprog t -8g} {}
Directory Freedom {:cf5} {:cky} {exec-d %utildir%\dfr.com} {}
List {:nf3} {setv file,%dldir%\}
{inpu file,File to List}
{exec-D %ext_li %file} {}
Qedit {:nf5} {setv file,%dldir%\}
{inpu file,File to Edit}
{exec-D %ramdr%\q.exe %file} {}
Dial Phone for voice {:nf6} {setv file}
{inpu file,Name or Number to Call}
{comp file} {ifco retu}
{exec-N phone %file} {}
Shell To DOS {:nf4} {shell}
{subs dr,1,1,%_hom}
{exec-n %dr:} {exec-n cd %_hom} {}
Mjog {:alj} {exec-w15 mjog /l} {retu}
See DOS Environment {:als} {exec-w15 set} {retu}
See a Commo variable {:al<} {setv file} {inpu file,See What Variable?}
{comp file} {ifco retu}
{setv-s value,%file}
{inpu %%file,Variable %file,%value} {retu}
Set a Commo variable {:al.} {setv inpu} {inpu inpu,Variable,Setting}
{comp inpu} {ifco retu}
{setv %%inpu} {retu}
Goto a Commo Routine {:al/} {setv file} {inpu file,GOTO ":routine"}
{comp file} {ifco retu}
{rope %_mac,retu}
{:gto_loop} {read line}
{inst line,:%file}
{ifco ,gto_loop}
{rclo}
{goto %file}
*---* Commo Help and quick reference *---*
Show Key Assignments {:alk} {exec-w60 type %_hom%assign.key} {}
List Commo DOCS {:hom} {exec l %ins_dir\*.doc} {}
Call Commo HELP {:alh} {help} {}
*---* Session History *---*
Enter Scrollback {:upa} {screen n,%savedir\savescro} {scro} {}
Edit Capture File {:dna} {exec-d %ramdr%\q.exe %_cap} {}
List Capture File {:lfa} {exec-d %ext_li %_cap} {}
Review Past Capture {:rta} {exec-d %ext_li %savedir\*.cap} {}
Capture Screen {:gr+} {screen y,%savedir\commo.scn} {}
Show Screen Capture {:gr-} {edit %savedir\commo.scn} {}
Review Call Log {:alr} {exec-d %ext_li %_hom%commo.log} {}
Edit ACTION File {:end} {inpu abbr,Which 2-letter ACTION File?}
{edit %_hom%action.%abbr} {}
Show ACTION history {:al1} {inpu abbr,Show ->%abbr%<- ACTION}
{comp abbr} {ifco retu}
{subs abbr,1,2,%abbr}
{exec-d %ext_li %_hom%*.%abbr} {}
*---* Messaging macros *---*
Ascii Upload {:ala} {asci %dldir%\,:} {}
Capture/Quote Message {:alo} {screen n,%_hom%quote.in}
{scro} {edit %_hom%quote.in}
{ifex %_hom%quote.in,,equote}
{rope %_hom%quote.in,equote}
{:nline} {read line} {send -> ~%line%|}
{goto nline}
{:equote} {send ~|} {exec-n del %_hom%quote.in} {}
*---* An automatic ASCII message entry system for PCBoards *---*
{:nf8} {setv file,%dldir%\} {inpu file,Name of Upload Message}
{ifex %file%,,n_e}
{parm ,,,,2} {send e|} {asciiup %file%,}
{parm ,,,,0} {send ~~|~~~sn|}
{lookfor %bbs_pmt}
{display ,,,^j^j}
{display ,18,1E,▌ Erase %file%? [Y/n] ▐^m}
{setlook 5,y_d,,}
{golook y_d,y}
{golook n_e,n}
{lookfor 'N' Skips Message Delete}
{:y_d} {exec-n del %file}
{:n_e} {send ^h}{disp ,18,, ^m}{}
*---* A guarded Alt-X command when leaving Commo from the terminal screen.
{:alx} {setv count,0} {setescape-p0 noex}
{disp 24,1,74, EXIT ^(Commo^) at "30" > }
{disp ,,70, Are you Sure? (Y/n) }
{disp 24,26}
{setv count,0} {setv resp} ;initialize variables
{:xlop} {setg 1,upct,n} {gets-h %resp,1,q_t} ;set up 1 second wait
{comp %resp,n} {ifco noex} ;compare response
{comp %resp,y} {ifco q_t} ;if resp = y, goto :q_t
{:upct} {disp 24,26,71,%count} {disp 24,26}
{incr %count} {comp %count,31}
{ifco-G q_t,xlop}{retu} ;loop or :q_t
{:noex} {disp 24,1,, ^m}
{retu} ;decided to stay
{:q_t} {exit} ;normal exit from Commo
*---* A tool to search a file for a string.
*---* Display the entire first line that includes a match.
{:cf3} {inpu file,Name to search from ADDRESS book}
{comp file}
{ifco retu}
{call search}
{setv oldrow,%_row} {setv oldcol,%_col}
{setv row,%_row} {decr row,2}
{disp %row,1,07, }
{comp addr} {ifco retu}
{disp %row,1,20,%addr } {disp %oldrow,%oldcol}
{setv addr} {setv oldcol} {setv row}
{setv file} {setv oldrow} {retu}
{:search} {rope %savedir\address,retu}
{:aloop} {read addr}
{inst addr,%file} {ifco ,aloop}
{rclo} {retu}
*---* Routines that might be useful to a remote sysop *---*
Aview at NLBBS {:alv} {door-m0} {send aview|} {setv dway,yes} {}
View ANSWER1 {:cf9} {exec-d %ext_li %savedir\answer1} {}
View COASTAL sessions {:cf0} {exec-d %ext_li %savedir\*.log} {}
*---* Date Routine *---*
{:datecode} {setv x,31}
{setv y,%mon} {decr y}
{call x_times_y}
{incr x,%day} {setv doy,%x}
{comp yea,91} {ifco-GE ,2000}
{decr yea,91} {goto yr_code}
{:2000} {incr yea,9}
{:yr_code} {setv x,372} {setv y,%yea}
{call x_times_y}
{incr x,%doy} {setv datecode,%x} {retu}
{:today} {setv day,%_day} ;This sets working variables
{setv mon,%_mon} ; to Commo's internal "today"
{setv yea,%_yea} ; values
{call datecode} ;Will return with today's code
{setv today,%datecode} ;Save the returned datecode
{:compday} {setv day,10}
{setv mon,4}
{setv yea,91}
{call datecode}
{decr today,%datecode}
{comp today,100}
{retu}
*---* Integer Math Routines *---*
* The result of "Y * X" is returned as "X"
* The result of "Y ÷ X" is returned as "X" and "REMAIN"
* The variable "Y" is then removed from variable space
{:x_times_y} {comp x,0} {ifco zero}
{comp y,0} {ifco zero}
{setv count,0} {setv z,0}
{:m_loop} {incr z,%x} {incr count}
{comp count,%y} {ifco-GE ,m_loop}
{setv x,%z} {setv z} {setv y} {retu}
{:zero} {setv x,0} {setv remain} {retu}
{:x_into_y} {comp y,0} {ifco zero}
{comp x,0} {setv x,undefined} {retu}
{setv count,0}
{:d_loop} {decr y,%x} {setv remain,%y} {incr count}
{comp remain,%x}{ifco-LE ,d_loop}
{setv x,%count} {setv y} {retu}
*---* Holding places in multiple ROPE files *---*
{setv partlist,1}
{setv filename,partlist}
{call to_place} {}
{:to_place} {setv count,1}
{rope %filename,retu}
{:inc_line} {read line}
{comp count,%%filename}
{incr count}
{ifco-E retu_pl}
{goto inc_line}
{:retu_pl} {incr %%filename} {rclo} {retu}
/==========================================================================
/ Download list tagging using COMMO built-in tools
/--------------------------------------------------------------------------
/ * Featuring dual-function Alt-D *
/ * depending on ON/OFF line Status *
/--------------------------------------------------------------------------
/ {:ald} {ifca mlist} ;Alt-D first checks for CARRIER
/ {dial} {} ;If NO, bring up dialing directory
/
/ {:mlist} {scre n,%_hom%dl-list} ;If CARRIER ONLINE, name screen image
/ {scro} ;Enter scrollback mode:
/ ; This is where you will tag files
/ ; Use the "W" facility in scrollback
/ ; Press C/R twice on each file to tag
/ ; Press ESC to quit tagging. Next,
/ {edit %_hom%dl-list} ;Enter COMMO's built-in editor:
/ ; Add or delete file names, 1 per line
/ ; Description text will be stripped
/ ; later in the macro.
/ {ifex %_hom%dl-list,dstart} {} ;Graceful exit if you deleted all lines.
/
/ {:dstart}{setv file}
/ {inpu file,C/R to Start DownLoad Now} ;A chance to exit
/ {comp file} {ifco go-dl} {} ; before start of d/l.
/
/ {:go-dl} {send d|} ;To the BBS, the download command
/ ; (or use the FLAG command)
/ {rope %_hom%dl-list,end-dl} ;Open file list for reading
/
/ {:next-1}{read file} ;Read one complete line into %file%
/ {subst file,1,12,%file} ;Strip all but first 12 characters
/ {send ~~~%file%|} ;Send filename to BBS
/ {goto next-1} ;Repeat read unti dl-list is all read
/
/ {:end-dl}{exec-n del %_hom%dl-list};Delete the list after sending
/ {send ~|} {} ;This macro is ended.
/ ;Waiting for Auto-Zmodem d/l?
/==========================================================================
/================================================================/
/ COMMO Macro that calls a WAFFLE BBS and checks for ZIPNEWS /
/----------------------------------------------------------------/
/ * This macro uses a variable called %pword2%.
/ * That variable is defined in my COMMO.FON file ... now I can
/ * freely share *ALL* of my COMMO.MAC file with the world.
/
/ {:cfb} {send open inet|}
/
/ {parm ,,,,390}
/ {setlook 30,,15,|}
/ {golook byz,try later}
/ {lookfor NEW:} {send ~cboldt|}
/ {lookfor Password:} {send %pword2|}
/ {lookfor %bbs_pmt} {send ~zipnews|}
/ {setlook 240,nozn,,}
/ {golook nozn,No new articles}
/ {lookfor Found:} {setg ,,l} {gets-H count,7}
/ {comp count,15} {ifco-L nozn}
/ {lookfor articles?} {send ~~y|}
/ {lookfoR ^xB00}
/ {exec-N dsz rz -m %dldir\inet%_mon%%_day.zip}
/ {:nozn}{setlook ,,10,n|}
/ {lookfor %bbs_pmt} {parm ,,,,600}
/ {send ~bye|} {parm ,,,,0}
/ {pause 5} {ifca ycar} {retu}
/ {:ycar}{setlook ,,5,|}
/ {lookfor %bbs_pmt} {send m|}
/ {return}
/================================================================
*---* Play Space *---* {:alp} {macr playsp} {}
{disp ,,,%_hom} {}
{:al9} {send I am ready to be switched to host!}
{paus 1}
{setg 30,retu,l} ;wait 30 seconds for password
{gets-p password,8} ;get password from "NOW-host"
{comp password,pick-one} ;remote guy picks his password
{ifco af5}
{retu}
*---* Macro to parse a command line string *---*
{:go_to} {inpu cmd_str,Command arg1 arg2 etc}
{comp cmd_str}
{ifco retu}
{setv count,0}
{:parse} {inst %cmd_str%, }
{ifco ,eparse}
{setv pos,%_pos}
{decr pos}
{subs arg%count,1,%pos,%cmd_str}
{incr pos,2}
{subs cmd_str,%pos,255,%cmd_str}
{incr count}
{goto parse}
{:eparse} {setv arg%count,%cmd_str}
{setv cmd_str}
{goto %arg0}
*---* Automatic mark and dial routines *---*
!{:sf7} {hold 05:30} {call nfb} {}
!{:nf7} {unmark} {mark Weather} {dial ,} {}
!{:nfa} {disp 24,1,1e, NLBBS & Weather after ... ^m}{hold 05:30}
! {mark 2 ■,3 ■} {setv rflag,001} {dial-c 40,}
! {:001} {ifex d:\qwk\dave\nlbbs.rep,legault}
! {:003} {mark weather} {setv rflag,aln} {dial-c 40,} {retu}
!{:nfb} {unmark} {mark 2 ■,3 ■} {dial-c 40,} {unmark} {}
!{:sfb} {:sfa} {mark 2 ■,3 ■,Maine,smvti,wolf's,direct,dataw,ledge,babb,abacu,after5}
{disp 6,21,1f,║ Weekend! Dial All ■ marked BBS's ║}
{goto aln}
!{:sf1} {unmark} {mark Node 3} {dial 15} {}
!{:sf2} {unmark} {mark Director} {dial 15} {}
!{:sf3} {exec-n d:\jr\jabber} {}
!{:wtr} {macl weather.mac,wtr}
{:legault} {unmark}
{mark legault■} {setv rflag,002}
{dial-c 40,}
{:002} {setv name,Chuck Seyboldt}
{setv qwkdr,d:\qwk} {setv repdr,d:\qwk}
{exec-n copy d:\qwk\dave\nlbbs.* b:}
{exec-n del d:\qwk\dave\nlbbs.*} {goto 003}
*---* This automatic mark-and-dial routine will send your .REP files *---*
* It bypasses .QWK download questions with the "SKIP" facility *
{:sf4} {ifex %repdr%\*.rep,rep_mark}
{exec-n del %ramdr%\rep_dir}
{setv skip} {retu}
{:rep_mark} {exec-n dir %repdr%\*.rep > %ramdr%\rep_dir}
{setv skip,y}
{rope %ramdr%\rep_dir,rep_dial}
{:r_loop} {read file}
{inst file,rep} {ifco ,r_loop}
{subs file,1,6,%file}
{mark %file} {goto r_loop}
{:rep_dial} {dial-c 45,} {goto sf4}
┌───────────────────────────────┐
│ Return Point From LOGON.MAC │
└───────────────────────────────┘
{:aln} {dial-c 45,} {retu} ;Multi-dial & Return
┌────────────────────────┐ ┌───────────────────────┐
│ Links from COMMO.FON │ │ Generic Logon Alone │
└────────────────────────┘ └───────────────────────┘
!{:pcb} {macl table.mac,pcb} ;TABLE.MAC can also sets prompts
!{:rma} {macl table.mac,rma} ; for a generic logon with NO MAILRUN.
!{:tag} {macl table.mac,tag} ;PCBoard, Remote Access,
!{:s-f} {macl table.mac,s-f} ;T.A.G, Spitfire, GAP, Wildcat! and
!{:gap} {macl table.mac,gap} ;MACROBBS are already supported.
!{:wc!} {macl table.mac,wc!}
!{:mac} {macl table.mac,mac} ;From TABLE.MAC to LOGON.MAC,glr
┌──────────────────────────────────┐
│ Generic Logon and Mail Routine │
└──────────────────────────────────┘
* With this tool you can mark multiple nodes of one BBS but make
* only one connect per unattended session.
FON manipulation
----------------
!{:nlb} {unmark 2 ■,3 ■} {macl table.mac,nlb} ;Control passes from
!{:smt} {macl table.mac,smt} ;COMMO.MAC to TABLE.MAC
!{:bab} {macl table.mac,bab}
!{:dir} {macl table.mac,dir} ;Note useage of same macro
!{:aft} {macl table.mac,aft} ;label in TABLE.MAC
!{:aba} {macl table.mac,aba} : as in COMMO.MAC
!{:wol} {macl table.mac,wol}
!{:mep} {macl table.mac,mep}
!{:dat} {macl table.mac,dat}
!{:led} {macl table.mac,led}
!{:esk} {macl table.mac,esk}